package {
	
	import flash.events.Event;
	import flash.events.EventDispatcher;
	
	public class CreateDocument extends EventDispatcher {
		
		public var text:String;
		private var textString:String;
		
		private var descriptor:XML;
		private var savedIndex:int; // start index for loop
		private var getElementText:GetElementText;
		private var resume:Boolean;
		
		/**
		 * Constrctor for new CreateDocument instances.
		 * @param array The array to be sorted.
		 */
		public function CreateDocument() {
			
		}
		
		/**
		 * Starts the CreateDocument operation.
		 */
		public function create(descriptor:XML):void {
			this.descriptor = descriptor;
			
			// initialize values
			textString = ""; 
			savedIndex = 0;
			
			descriptorLoop();
		}
		
		// ENTER_FRAME loop for asynchronous processing
		private function descriptorLoop():void {
			
			var i:int;
			var n:int = descriptor.text.length();
			for (i=savedIndex; i<n; i++) {
				
				resume = false;
				getElementText = new GetElementText();
				getElementText.addEventListener(Event.COMPLETE, getElementTextComplete);
				getElementText.load( descriptor.text[i] );
				
				if (!resume){
					// asynchronous
					resume = true;
					savedIndex = i + 1;
					return;
				}
				
				// synchronous; continue loop
			}
			
			// loop has completed without exiting
			// process is complete
			
			// copy result into user-accessible variable
			text = textString;
			
			// cleanup
			textString = null;
			getElementText = null;
			
			// signal completion
			dispatchEvent(new Event(Event.COMPLETE));
		}
		
		private function getElementTextComplete(event:Event):void {
			
			// cleanup listener
			getElementText.removeEventListener(Event.COMPLETE, getElementTextComplete);
			
			// update text text
			if (textString) textString += "\n";
			textString += getElementText.text;
			
			if (resume){
				// state set by the loop to indicate an
				// asynchronous operation; restart loop
				descriptorLoop();
			}else{
				// toggle the resume flag to indicate
				// the complete event has fired synchronously
				// and the descriptorLoop call can continue
				resume = true;
			}
		}
	}
}